TerraForged/TerraForgedAPI/build.gradle

buildscript {
    repositories {
        jcenter()
        mavenCentral()
        maven { url "https://files.minecraftforge.net/maven" }
    }
    dependencies {
        classpath group: "net.minecraftforge.gradle", name: "ForgeGradle", version: "3.+", changing: true
    }
}

apply plugin: "net.minecraftforge.gradle"
apply plugin: "eclipse"
apply plugin: "maven"

version = "${version}-mc${mc_version}"
archivesBaseName = "TerraForgedAPI"

repositories {
    jcenter()
    mavenCentral()
}

dependencies {
    minecraft "net.minecraftforge:forge:${mc_version}-${forge_version}"
    compile project(":Noise2D")
    compile project(":FeatureManager")
    compile project(":TerraForgedCore")
}

minecraft {
    mappings channel: mcp_channel, version: mcp_version
}

task deobfApiJar(type: Jar, dependsOn: classes) {
    classifier = "deobf"
    duplicatesStrategy = "EXCLUDE"
    from("$buildDir/classes/java/main")
    from(project(":Noise2D").buildDir.getPath() + "/classes/java/main")
    from(project(":FeatureManager").buildDir.getPath() + "/classes/java/main")
    from(project(":TerraForgedCore").buildDir.getPath() + "/classes/java/main")
}

jar {
    dependsOn(deobfApiJar)
}

artifacts{
    archives deobfApiJar
}

uploadArchives {
    repositories {
        mavenDeployer {
            repository(url: "https://io.terraforged.com/repository/maven/") {
                authentication(userName: System.getenv("MAVEN_USER"), password: System.getenv("MAVEN_PASS"))
            }
        }
    }
}